set export

modName := "finalbeta"
modVersion := "1.4.0"

setup:
	./cleanup.sh
	./decompile.sh
	just create-bakups

[working-directory: './src/minecraft/net/minecraft/src/']
create-bakups:
	#!/usr/bin/env bash
	(for file in $(fd --no-ignore ".java"); do
		[ -e "$file" ] || continue
		bak="$file.bak"
		cp "$file" "$bak"
	done)

[working-directory: './src/minecraft/net/minecraft/src/']
apply-patches:
	#!/usr/bin/env bash
	(for file in $(fd --no-ignore ".java.bak"); do
		core="${file/.bak/}"
		patch="${core}.patch"
		rm "$core"
		cp "$file" "$core"
		patch < "$patch"
	done)

[working-directory: './src/minecraft/net/minecraft/src/']
create-patches:
	#!/usr/bin/env bash
	(for file in $(fd --no-ignore ".java.bak"); do
		core="${file/.bak/}"

		# check to see if the file has been changed
		check="$(cmp -s $file $core && echo 1 || echo 0)"
		[ $check -eq 0 ] || continue

		patch="${core}.patch"
		echo "Creating patch file for $core"
		diff -Nau "$file" "$core" > "$patch" || true
	done)

build:
	# Delete previous builds
	fd . './builds' -e .zip --exec rm
	just create-patches
	./recompile.sh
	./reobfuscate.sh
	(cd ./reobf/minecraft && zip -r "../../builds/${modName}-${modVersion}-modloader.zip" ./*)